Forgive the long post, but thought I'd share:
Hunter specific:
************
-----------------------------------------------------------------------------------------
Opener - This macro sets Hunter's Mark and controls your pet's attack.
Click : set the mark, cast your pet's speed boost, send in pet
Alt-click : abort your pet's attack in case you mark the wrong mob,
or are conducting a pet pull
#showtooltip
/petattack
/cast Hunter's Mark
/cast Dash
/cast Dive
/cast Charge
/cast Warp
/petfollow [mod:alt]
----------------------------------------------------------------------------------------
One Stop Pet Care Shop - This macro will cast the pet spells needed according to the situation
Click - Pet is alive but dismissed: Call Pet
- Pet is dead : Revive Pet
- Pet is active : Mend Pet
Alt-click : Dismiss Pet
Control-click : Revive Pet (in case you are unable to target your pet's
corpse)
#showtooltip
/cast [mod:ctrl] Revive Pet;
/cast [mod:alt] Dismiss Pet; [target=pet, dead] Revive Pet; [nopet] Call Pet; [nomodifier] Mend Pet;
Variation - This macro includes only Feed Pet and Mend Pet. It will display the number of food items currently in your bag
Click : Feed Pet
Alt-click : Mend Pet
#show [nomod] Smoked Talbuk Venison; Mend Pet;
/cast [nomod] Feed Pet;
/use [nomod] Smoked Talbuk Venison;
/cast [mod:alt] Mend Pet;
-----------------------------------------------------------------------------------------
DPS Shot Rotation - This macro fires steady shots and does a low threat pull. It will automatically target your pet's target if you are solo-grinding. It also casts Kill Command whenever it is available.
Click : cast Kill Command
- no group : target your pet's target
- out of combat : casts lowest Arcane and stops firing
- in combat : casts Steady Shot
Alt-Click : casts Intimidation
/target [nogroup] pettarget
/cast [target=pettarget, exists] Kill Command
/cast [nocombat] Arcane Shot(Rank 1)
/stopcasting [nocombat]
/cast [nomod:alt, combat] Steady Shot;
/cast [mod:alt] Intimidation
-----------------------------------------------------------------------------------------
Oh No! - This macro cycles through all of my defensive abilities.
Click : cast Feign Death if the cooldown is up
use a Fel Blossom
spam Disengage
Alt-click : Scare Beast
#showtooltip
/castsequence [nomod:alt] reset=30 Feign Death, Fel Blossom, Disengage, Disengage, Disengage, Disengage, Disengage, Disengage, Disengage; [mod:alt] Scare Beast;
-----------------------------------------------------------------------------------------
Stings - All of the useful Stings
Click : Scorpid Sting
Alt-click : Serpent Sting
Control-click : Tranq Shot
#showtooltip
/target [nogroup] pettarget
/cast [mod:alt] Serpent Sting; [mod:ctrl] Tranquilizing Shot; Scorpid Sting;
----------------------------------------------------------------------------------------
Misdirect - This macro will set up and use Misdirect on a pre-specified tank. If there is cc present, allow the third attack to be an autoshot. I have my mount in slot 1 1, so this icon is visible until 10 seconds before MD is available again
Right-click : set focus on target (the tank)
Alt-click : cast Misdirect on your focus
Click : cycle your highest threat attacks
#showtooltip
/cast [button:1, mod:alt, target=focus] Misdirection
/castsequence [button:1, nomod] reset=110 Aimed Shot, Arcane Shot, Multi-Shot, 1 1
/focus [button:2] target
----------------------------------------------------------------------------------------
Regen - This will cast Prowl and Shadowmeld if you have the abilities, give you your choice of normal food or any of the useful buff-foods, and drink.
#showtooltip
/use [nomod] Telaari Grapes
/use [mod:alt] Warp Burger
/use [mod:ctrl] Ravager Dog
/use [mod:shift] Spicy Hot Talbuk
/use Purified Draenic Water
/cast Prowl
/cast Shadowmeld
-----------------------------------------------------------------------------------------
Chain Trapping - This macro combines the freezing trap with threat spike attacks. The main weakness is that although Distracting is useful because it does not break traps, it does not in fact generate much threat (less than a white damage shot). It is best to pull the mob at an angle to avoid it running through any aoe effects of the tank's. For solo use, this casts Multi-shot to pull a couple of mobs off your pet.
Right-click : set focus
Click : lay a Freezing Trap
Alt-click - grouped : cast Distracting Shot
- solo : cast Multi-Shot
#showtooltip
/focus [button:2] target
/cast [button:1, nomod] Freezing Trap
/cast [button:1, mod:alt, target=focus, group] Distracting Shot
/cast [button:1, mod:alt, nogroup] Multi-Shot;
-----------------------------------------------------------------------------------------
Non-Specific
**********
----------------------------------------------------------------------------------------
Fishing - This macro handles all your fishing needs
Click - carrying weapon : equip your Fishing Pole
- carrying Pole : cast Fishing
Alt-click : apply a fishing lure
Right-click : re-equip your weapon
#show [nomod:alt] Fishing; [modifier:alt] Bright Baubles
/equip [noequipped: Fishing Pole, button:1] Seth's
/equip [button:2] Sonic
/use [mod:alt] Bright Baubles
/use [mod:alt] 16
/cast [nomod, button:1, equipped:Fishing Pole] Fishing
----------------------------------------------------------------------------------------
Mount - This macro covers mounting and hearthing
Click : use a random flying mount
Right-click : use a random ground mount
Alt-click : Hearth
/use [mod:alt] Hearthstone
/userandom [nomounted, button:1] Purple Riding Nether Ray, Swift Purple Gryphon
/userandom [button:2] Swift White Steed, Reins of the Swift Stormsaber, Reins of the Cobalt War Talbuk, Great Purple Elekk
/dismount [mounted]
----------------------------------------------------------------------------------------
Mage Munchies - Similar to Regen, except with Mage Conjured food. If you are running with a mage that is handing out food and drink separately, alt-click will use only the drink. If I have no mage food, I use this as a one-click Prowl/Shadowmeld
#showtooltip
/use Conjured Manna Biscuit
/use [mod:alt] Conjured Glacier Water
/use [nomod] Conjured Glacier Water
/use [nomod] Conjured Croissant
/cast Prowl
/cast Shadowmeld
----------------------------------------------------------------------------------------
Food and Drink - These macros will use a potion if you are in combat or food/drink if you are not. This is a nice visual cue for whether or not you are in combat. It also prevents you from using your potions when it is not necessary to do so. They will use the quest reward (skettis escort) if you have them, if not, it will use a crafted/dropped potion. The food one will also use a Healthstone on alt-click, but I generally put those in their own hotbar slot anyway.
#showtooltip
/use [combat] Unstable Mana Potion;
/use [combat] Super Mana Potion;
/use [nocombat] Purified Draenic Water;
/cast Prowl
/cast [nocombat] Shadowmeld;
#showtooltip
/use [combat, nomodifier] Volatile Healing Potion;
/use [combat, nomodifier] Super Healing Potion;
/use [nocombat, nomodifier] Telaari Grapes
/use [combat, modifier:alt] Master Healthstone;
/cast Prowl
/cast [nocombat] Shadowmeld
=================================================
-I use the (?) icon almost all the time, along with the #showtooltip command, you can see what your macros will be doing under any given circumstances.
-It can be useful to use bag/slot numbers rather than names to specify an item in your macro. I recently replaced all of my mount names with 1 1, 1 2, etc. This frees up quite a few characters in your macros if you start running over the allotted length. The only hang up is to be sure that if your macro removes anything or replaces anything in your bags (an equip trinket or equip fishing pole for example) it will place it back in the original slot.